***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan. 10, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5546V-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.875
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=220.2  VTO=3.95  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=1.415e12  gamma=0.94)
Rd     d1    d2    3.6464e-3    TC=4.48e-3,9.05e-6
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=44  TBV1=5.336e-4 TBV2=7.05e-8  CJO=1.204e-9  M=1.319  VJ=11.003)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=8.118e-12  N=1.08  RS=4e-8  EG=1.13  TT=20n IKF=41.471 tikf=7.5e-3)
Rdiode  d1  21    1.865e-3 TC=4.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   3.162e-10
.MODEL     DGD    D(cjo=3.072e-10   M=1.688   VJ=7.866)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    8.84e-10
.ENDS PJQ5546V-AU
*$
